BLACKHOLEDCB	FCB	1	DONE
	FDB	0	LAST ERROR
	FDB	BLACKHOLESTR
	FDB	NEXTDEVICEDCB
	FDB	BLACKHOLEDRIVER
BLACKHOLESTR	FCC	'BLACKHOLE:'
	FCB	0
*
NEXTDEVICEDCB	SET	BLACKHOLEDCB
*
BLACKHOLEDRIVER	FDB	BLACKHOLEIT
	FDB	BLACKHOLEIT
	FDB	BLACKHOLEEOF
	FDB	BLACKHOLEIT
	FDB	BLACKHOLEEOF
	FDB	BLACKHOLEIT
	FDB	BLACKHOLEIT	CREATE
	FDB	BLACKHOLEIT
	FDB	BLACKHOLEIT
	FDB	BLACKHOLECTL
	FDB	BLACKHOLESTAT
	FDB	BLACKHOLEIT
	FDB	BLACKHOLEIT
*
*	FOLKLORE HAS IT THAT SOME WHERE OFF THE COAST OF FLORIDA
*	THERE EXISTS A REGION WHERE SHIPS AND PLANES HAVE MISTERIOUSLY
*	DISAPPEARED.  SOME THINK THAT THIS PLACE IS A BREAK-DOWN
*	OF TIME & SPACE.  OTHERS SUGGEST THAT UFO'S HAVE LANDED
*	THERE AND ARE USING IT A BASE OF OPERATIONS. OTHERS THINK
*	THAT THE DEVIL HIMSELF IS THERE, STEALING SOULS FOR THE UNDERWORLD.
*
*	THIS PLACE, CALLED THE DEVIL'S TRIANGLE BY SOME, EXISTS NOT ONLY
*	IN THE WATERS OF THE ATLANTIC BUT HERE, IN SDOS.  EYE-WITNESS
*	REPORTS STATE MANY TIMES OVER THAT BITS, BYTES AND YES, EVEN WHOLE
*	DISK FILES HAVE DARED THE MURKY QND DANGEROUS SUBROUTINES OF THE
*	"BLACKHOLE:" NEVER TO BE SEEN AGAIN.  EVEN THE US AIR FORCE HAS
*	SENT FIGHTER JET AIRCRAFT INTO THE "BLACKHOLE:" DRIVER, NEVER TO
*	BE SEEN AGAIN
*
*	SO BEWARE, YOU WHO ARE ABOUT TO VENTURE INTO THIS DRIVER!
*	YOU MAY NEVER COME OUT!
*
BLACKHOLEIT	OKRTS
BLACKHOLEEOF	JSR	SDOS+SDOS:ERROR
	FDB	ERR:EOFHIT
BLACKHOLESTAT	CMPA	#SC:GETPOS
	BEQ	BLACKHOLEPOS
	CMPA	#SC:GETCOL
	BEQ	BLACKHOLECOL
	CMPA	#SC:GETEOF
	BEQ	BLACKHOLEGEOF
	CMPA	#SC:GETTYPE
	BEQ	BLACKHOLETYPE
	BRA	BLACKHOLEIT	YUMMMY!
*
BLACKHOLEPOS	JSR	SDOS+SDOS:CHECKRDLEN
	FDB	4
	LDX	SCBLK:RDBUF,X
	CLR	STATUS:DATA,X
	CLR	STATUS:DATA+1,X
	CLR	STATUS:DATA+2,X
	CLR	STATUS:DATA+3,X
	OKRTS
*
BLACKHOLECOL	JSR	SDOS+SDOS:CHECKRDLEN
	FDB	1
	LDX	SCBLK:RDBUF,X
	CLR	STATUS:DATA,X
	OKRTS
*
BLACKHOLEGEOF	JSR	SDOS+SDOS:CHECKRDLEN
	FDB	1
	LDX	SCBLK:RDBUF,X
	CLR	STATUS:DATA,X
	OKRTS
*
BLACKHOLETYPE	JSR	SDOS+SDOS:CHECKRDLEN
	FDB	1
	LDX	SCBLK:RDBUF,X
	LDAA	#DVTYP.DUMMY
	STAA	DVTYP:TYPE,X
	OKRTS
*
BLACKHOLECTL	CMPA	#CC:DISMOUNTDISK
	BNE	BLACKHOLEIT
	LDAA	#$80
	ORAA	TTYFLAGS
	STAA	TTYFLAGS
	OKRTS
