; $VER: Install HippoPlayer
;
;       Installer script for HippoPlayer.
;
;(C) 31.X.1995 Tomasz Kepa
;
; Major modifications by K-P
;


(complete 0)

(set DEST-DIR
  (askdir
    (prompt "Where do you want to install HippoPlayer?")
    (help (cat @askdir-help)
    )
    (default "SYS:")
  )
)

(delete "s:hip-script")

(copyfiles
  (source "HiP")
  (dest DEST-DIR)
)

(set NUMBER
  (askchoice
    (prompt "Select the icon for HippoPlayer")
    (help
      (cat
        "You can choose one icon for HippoPlayer. There are"
        "\nsome icons for normal WB with 4 colors, couple"
        "\nof colorful icons for MagicWB users and one for"
        "\nNewIcons.\n\n"
        @askchoice-help
      )
    )
    (choices
      "Face portrait (4 colors; all kickstarts)"
      "Smaller face portrait (4 colors; all kickstarts)"
      "Hippo-text (MagicWB)"
      "Colorful face portrait (MagicWB)"
      "Speakers (MagicWB)"
      "Another face portrait (MagicWB)"
      "Whole Hippo (NewIcons)"
    )
    (default 0)
  )
)

(complete 10)

(if (= NUMBER 0)
  (copyfiles
    (source "HiP.info")
    (dest DEST-DIR)
  )
)

(if (= NUMBER 1)
  (copyfiles
    (source "Icons/HiP2.info")
    (dest DEST-DIR)
    (newname "HiP.info")
  )
)

(if (= NUMBER 2)
  (copyfiles
    (source "Icons/HiP_MWB.info")
    (dest DEST-DIR)
    (newname "HiP.info")
  )
)

(if (= NUMBER 3)
  (copyfiles
    (source "Icons/HiP_MWB2.info")
    (dest DEST-DIR)
    (newname "HiP.info")
  )
)

(if (= NUMBER 4)
  (copyfiles
    (source "Icons/HiP_MWB3.info")
    (dest DEST-DIR)
    (newname "HiP.info")
  )
)

(if (= NUMBER 5)
  (copyfiles
    (source "Icons/HiP_MWB4.info")
    (dest DEST-DIR)
    (newname "HiP.info")
  )
)

(if (= NUMBER 6)
  (copyfiles
    (source "Icons/HiP_NI.info")
    (dest DEST-DIR)
    (newname "HiP.info")
  )
)

(set DOCS
  (askbool
    (prompt "\n\n\n\n\nDo you want to install the documentation?")
    (help (cat
	"You really should."
        )
    )
    (default 1)
  )
)

(complete 20)

(if (= DOCS 1)
  (set DOC
    (askoptions
      (prompt "Which type of documentation do you want?")
      (help (cat @askoptions-help))
      (choices
        "ASCII"
        "AmigaGuide"
      )
      (default 2)
    )
  )
)


(if (= DOCS 1)
 (set DEST-DIR2
   (askdir
     (prompt "Select destination directory for the documentation")
     (help (cat @askdir-help)
     )
     (default DEST-DIR)
   )
 )
) 

(if (= DOC 1)
  (copyfiles
    (source "")
    (dest DEST-DIR2)
    (choices
      "HiP.doc"
      "HiP.doc.info"
    )
  )
)

(complete 30)

(if (= DOC 2)
  (copyfiles
    (source "")
    (dest DEST-DIR2)
    (choices
      "HiP.guide"
      "HiP.guide.info"
    )
  )
)

(if (= DOC 3)
  (copyfiles
    (source "")
    (dest DEST-DIR2)
    (choices
      "HiP.doc"
      "HiP.doc.info"
      "HiP.guide"
      "HiP.guide.info"
    )
  )
)


(complete 40)

(copyfiles
  (source "")
  (dest
    (askdir
      (prompt
        (cat
          "Select destination directory for HippoPlayer.group"
        )
      )
      (help
        (cat
	  "This file contains some playroutines for different music"
	  " formats. It is adviced to install it."
          " The place of HippoPlayer.group can also be defined"
          " later in HippoPlayer.\n\n"
          @askdir-help
        )
      )
      (default "S:")
    )
  )
  (choices
    "HippoPlayer.group"
  )
)

(complete 50)


(if (exists "S:HippoPlayer.PS3M")
  (if (=
    (askbool
      (prompt (cat
            "\n\n\n\n\nDo you want to overwrite S:HippoPlayer.PS3M?"
          )
      )
      (help
        (cat "Don't overwrite if you want to keep your PS3M settings." 
	     "\n Do overwrite if you're updating from v2.12 or older.")
      )
    ) 1)
    (copyfiles
      (source "HippoPlayer.PS3M")
      (dest "S:")
    )
  )
)

(complete 60)

(copylib
  (source "Libs/ReqTools.library")
  (dest "Libs:")
  (confirm)
  (prompt "\n\n\nDo you want to install the reqtools.library?")
  (help
    (cat
      "Reqtools.library is needed for requesters in HippoPlayer."
      " Library version for kickstart 1.2/1.3 is included.\n\n"
      @copylib-help
    )
  )
)

(complete 70)

(if (=
  (askbool
    (prompt "\n\n\n\n\nDo you want to install the ARexx scripts?")
    (help
      (cat
        "There are some simple scripts included. "
 	"Not really useful, but might be of some help as examples.\n\n"
      )
    )
  ) 1)
  (copyfiles
    (source "ARexx")
    (dest
      (askdir
        (prompt "Select destination directory for ARexx scripts")
        (help
          (cat
            @askdir-help
          )
        )
        (default "REXX:")
      )
    )
    (all)
  )
)

(complete 80)

(if (=
  (askbool
    (prompt "\n\n\n\n\nDo you want to copy HippoPlayer brush for ToolManager somewhere?")
    (help
      (cat
      )
    )
  ) 1)
  (copyfiles
    (source "Brushes")
    (dest
      (askdir
        (prompt "Select destination directory for the brush")
        (help
          (cat
            @askdir-help
          )
        )
        (default "SYS:")
      )
    )
    (all)
  )
)


(complete 100)

(message
  (cat
    "\n\n\n\n"
    "You should also look what the Support/ directory contains. "
    "There are some stuff that might be useful or fun.\n\n"
    "Finally, READ THE DOC!"
  )
)
