echo You may Install one of two ways:
echo
echo SMALL install will only install the STARTUP DISK to
echo your hard drive. You MUST play from floppies.
echo Approximate hard drive space required:	1.2 Meg
echo
echo COMPLETE install will install all files to your hard
echo drive. The entire game will be played from a hard
echo drive. Approximate hard drive space required:	8.0 Meg
echo
echo Would you like to install (S)mall, (C)omplete or (E)xit?
pick sce small large Exit2

:small
clear
space %1: 1200	NoSpace
godir %1:\sierra\lsl5	CantCreate
rem	Copy over the necessary files.
echo Copying Startup Files ...
copy %2:*.drv
copy %2:version
copy %2:scid*.exe
copy %2:interp.txt
copy %2:resource.000
copy %2:resource.map
copy %2:install.exe
copy %2:install.hlp
copy %2:install.txt
copy %2:lsl5rs.bat %1:\lsl5.bat
copy %2:lsl5rs.bat %1:\sierra\lsl5.bat
copy %2:lsl5.bat lsl5.bat
copy %2:sierra.bat sierra.bat
copy %2:\bonus\*.*

echo %3 > resource.cfg

goto exit


:large
clear
space %1: 8000	NoSpace
godir %1:\sierra\lsl5	CantCreate
rem	Copy over the necessary files.
echo Copying Startup Files ...
copy %2:*.drv
copy %2:scid*.exe
copy %2:interp.txt
copy %2:version
copy %2:tandy3v.drv
copy %2:resource.000
copy %2:resource.map
copy %2:install.exe
copy %2:install.hlp
copy %2:install.txt
copy %2:lsl5rs.bat %1:\lsl5.bat
copy %2:lsl5rs.bat %1:\sierra\lsl5.bat
copy %2:lsl5h.bat lsl5.bat
copy %2:sierrah.bat sierra.bat
copy %2:\bonus\*.*

echo %3 > resource.cfg

echo Copying Game files...
exists %2:resource.001 Please insert the disk labeled "Disk 1" in drive %2:.
copy %2:*.*
exists %2:resource.002 Please insert the disk labeled "Disk 2" in drive %2:.
copy %2:*.*
exists %2:resource.003 Please insert the disk labeled "Disk 3" in drive %2:.
copy %2:*.*
exists %2:resource.004 Please insert the disk labeled "Disk 4" in drive %2:.
copy %2:*.*
exists %2:resource.005 Please insert the disk labeled "Disk 5" in drive %2:.
copy %2:*.*
exists %2:resource.006 Please insert the disk labeled "Disk 6" in drive %2:.
copy %2:*.*
exists %2:resource.007 Please insert the disk labeled "Disk 7" in drive %2:.
copy %2:*.*


:exit
clear
echo
echo ˙To play NOW:
echo ˙   Type lsl5 [ENTER].
echo
echo ˙To play LATER:
echo ˙   From the root directory of %1:,
echo ˙   Type lsl5 and press [ENTER].
echo
pause
goto Exit2


:NoSpace
clear
echo
echo There is not enough space on %1: to install Leisure Suit Larry 5!
rem determine which message to bring up.
space %1: 1200 NoSmall
echo 8.0 megabytes of disk space are necessary.
echo
echo SMALL install will only install the STARTUP DISK
echo to your hard drive. You MUST play from floppies.
echo SMALL install is recommended, due to insufficient
echo hard drive space.
echo
echo Would you like to install (S)mall or (E)xit?
pick se small Exit2


:NoSmall
alert 1.2 megabytes of disk space are necessary.
end


:Exit2
end


:CantCreate
alert Unable to create directory %1:\sierra\lsl5
end
