1 REMark format (c) Timo Salmi
2 REMark Translated into English Sat 1992 Apr 04 09:40:28
3 REMark version 1.0
4 :
100 CLEAR:kokoaika=DATE
110 reset(8)
120 bon=-1
130 ots$="FORMAT TWO MICROCARTRIDGES"
140 p_alku "FORMAT","01.03.85",ots$
150 :
160 PRINT\"INSERT MICROCARTRIDGES IN BOTH DRIVES"
170 FLASH 1
180 PRINT"WARNING: ";
190 FLASH 0
200 PRINT"ALL POTENTIAL OLD MATERIAL"
210 PRINT"ON THE CARTRIDGES WILL BE LOST"
220 INPUT\"CONTINUE (y/n=enter)?"!v$
230 IF NOT v$=="y":PRINT"NOT CONFIRMED"\"READY":STOP
240 AT 9,0:CLS 2:CLS 3
250 PRINT"CYCLES? 5"
260 AT 9,12:INPUT kier$
270 IF kier$="":kier$=5
280 IF kier$<"0" OR kier$>"10":p_beep1:GO TO 240
290 :
300 IF kier$>"0" THEN 
310  FOR i=1 TO kier$
320   INK 6
330   PRINT"CYCLE"!i
340   INK 7
350   FORMAT mdv1_tyhja
360   FORMAT mdv2_tyhja
370  END FOR i
380 END IF 
390 INK 7
400 p_beep2:PRINT
410 PRINT"GIVE NAMES to CARTRIDGES (y/n)?";
420 INPUT!v$
430 IF NOT (v$=="y" OR v$=="n"):p_beep1:GO TO 410
440 IF v$=="y" THEN 
450  INPUT"mdv1_?"!h1$
460  p_mdvnimtark h1$,ok:REMark 27000
470  IF NOT ok:PRINT"NON-STANDARD NAME":p_beep1:GO TO 450
480  INPUT"mdv2_?"!h2$
490  p_mdvnimtark h2$,ok:REMark 27000
500  IF NOT ok:PRINT"NON-STANDARD NAME":p_beep1:GO TO 480
510  :
520  FORMAT "mdv1_"&h1$
530  FORMAT "mdv2_"&h2$
540 END IF 
550 :
560 PRINT
570 DIR mdv1_:DIR mdv2_
580 p_beep2:p_valmis(1):STOP
590 :
19050 DEFine PROCedure p_beep1
19060  IF bon:BEEP 4000,70
19070 END DEFine p_beep1
19080 :
19090 DEFine PROCedure p_beep2
19100  IF bon:BEEP 32000,70,70,1500,.1
19110 END DEFine p_beep2
19120 :
20000 DEFine PROCedure p_alku(ohj$,tpvm$,ots$)
20010  LOCal pv$,vsi:REMark 20.09.85
20020  OPEN#3,scr_513x256a0x0:PAPER#3,0:CLS#3:CLOSE#3
20030  WINDOW#1,448,200,32,16
20040  FLASH#1,0
20050  PAPER#1,2:INK#1,7:CLS#1
20060  ohj$=ohj$&", TIMO SALMI "&tpvm$
20070  PRINT#1,ohj$\ots$
20080  pv$=DATE$:vsi=pv$(1 TO 4)
20090  PRINT#1,DAY$!DATE$
20100  WINDOW#0,448,40,32,216
20110  PAPER#0,0:INK#0,7:CLS#0
20120 END DEFine p_alku
20130 :
27300 DEFine PROCedure p_mdvnimtark(a$,ok)
27310  LOCal a,i,c
27320  a=LEN(a$):ok=-1
27330  IF a<1:ok=0:RETurn 
27340  IF a>10:PRINT"EXCEEDS 10 CHARACTERS":ok=0:RETurn 
27350  FOR i=1 TO a
27360   c=CODE(a$(i))
27370   SELect ON c
27380    ON c=0 TO 47,58 TO 64,91 TO 94,96,123 TO 255
27390     PRINT"CHARACTER"!CHR$(c)
27400     ok=0:RETurn 
27410   END SELect 
27420  END FOR i
27430 END DEFine p_mdvnimtark
27440 :
30000 DEFine PROCedure p_valmis(ch%)
30010  LOCal tl,ml,sl
30020  PRINT#ch%,"READY,"!"elapsed"!"time"!;
30030  sl=DATE-kokoaika
30040  tl=INT(sl/3600):sl=sl-tl*3600
30050  ml=INT(sl/60):sl=sl-60*ml
30060  IF tl>0 THEN PRINT#ch%,tl!"h"!;
30070  IF ml>0 OR tl>0 THEN PRINT#ch%,ml!"min"!;
30080  PRINT#ch%,sl!"sec"
30090 END DEFine p_valmis
30100 :
31000 DEFine PROCedure reset(i)
31010  LOCal il:MODE i
31020  FOR il=1,2:OPEN#il,con_:END FOR il
31030  WINDOW 512,256,0,0:PAPER 0:CLS
31040  WINDOW#0,448,40-(i=4),32,216+(i=4)
31050  WINDOW#2,448,200,32,16:PAPER#2,1:INK#2,7
31060  WINDOW 448+8*(i=4),200+2*(i=4),32-4*(i=4),16-(i=4)
31070  PAPER 2*(i=8):BORDER (i=4),4*(i=4)
31080  FOR il=0,1,2:CSIZE#il,(i=4)+2*(i=8),0:END FOR il
31090  PAPER#0,0:INK#0,7-3*(i=0):INK 7:CLS
31100  SCALE 100,0,0:FILL 0
31110 END DEFine reset
31120 :
31990 STOP
32000 vsave 1:STOP
32010 vsave 2:STOP
32020 vsave 3:STOP
32030 vsave 4:STOP
32040 vsave 5:STOP
32050 vsave 6:STOP
32060 DEFine PROCedure vsave(dr)
32070  LOCal avl$(42),bvl$(42),dvl$(6,5):avl$="format"
32080  bvl$=DATE$:bvl$=bvl$(1 TO 4)
32090  IF bvl$<>1992 THEN 
32100   PRINT#0,DAY$!DATE$!"Not saved, set SDATE"
32110   BEEP 4000,12:STOP:END IF 
32120  ver1%=1:ver2%=0
32130  dvl$(1)="mdv1_":dvl$(2)="mdv2_"
32140  dvl$(3)="fdk1_":dvl$(4)="fdk2_"
32150  dvl$(5)="ram1_":dvl$(6)="ram2_"
32160  bvl$=dvl$(dr)&avl$
32170  DELETE bvl$:OPEN_NEW#3,bvl$:ver%=ver2%+1
32180  PRINT#3,"1 REMark ";avl$!"(c) Timo Salmi"
32190  PRINT#3,"2 REMark ";DAY$!DATE$
32200  PRINT#3,"3 REMark version"!ver1%;".";ver%
32210  PRINT#3,"4 :"
32220  LIST#3,100 TO 32110
32230  PRINT#3,"32120  ver1%=";ver1%;":ver2%=";ver%
32240  LIST#3,32130 TO:CLOSE#3
32250  PRINT#0,"Saved"!bvl$!"version"!ver1%;".";ver%
32260 END DEFine vsave
