1 REMark circledemo (c) Timo Salmi
2 REMark Translated into English Sat 1992 Apr 04 18:25:47
3 REMark version 1.0
4 :
100 CLEAR:kokoaika=DATE
110 p_demologo"CIRCLEDEMO","12.11.85"
120 :
130 FOR i=1 TO 10:p_circles:PAUSE 100
140 reset(8)
150 p_valmis 0
160 STOP
170 :
180 DEFine PROCedure p_circles
190  LOCal i,e
200  WINDOW 513,256,0,0
205  MODE 0
210  PAPER RND(0 TO 7)
220  CLS
230  e=1/RND^.5
240  s=2/RND(1 TO 4)
250  FOR i=90 TO 1 STEP -s
260   INK RND(0 TO 255)
270   CIRCLE 82,50,i,e,0
280  END FOR i
290 END DEFine p_cirles
300 :
20500 DEFine PROCedure p_demologo(ohj$,tpvm$)
20510  LOCal pv$,vsi,v$:MODE 8
20520  WINDOW 513,256,0,0:PAPER 0:CLS
20530  WINDOW#0,448,40,32,216:PAPER#0,0:INK#0,7:CSIZE#0,2,0
20540  WINDOW 448,200,32,16
20550  PAPER 2:INK 7:CLS
20560  CSIZE 3,1:CURSOR 224-8*10,60
20570  INK 5:PRINT"Timo Salmi"
20580  CURSOR 224-8*8,80
20590  INK 6:PRINT"QL DEMOS"
20600  INK 1
20610  CURSOR 224-8*LEN(ohj$),120
20620  FLASH 0:PRINT ohj$:FLASH 0
20630  INK 7:CSIZE 2,0
20640  CURSOR 222-6*LEN(tpvm$),100
20650  PRINT tpvm$
20660  pv$=DATE$:vsi=pv$(1 TO 4)
20670  INK 0:AT 0,0:PRINT DAY$!DATE$
20680  INK 4:CURSOR 0,190
20690  INPUT"CONTINUE: PRESS ENTER?"!v$
20700 END DEFine p_demologo
20710 :
30000 DEFine PROCedure p_valmis(ch%)
30010  LOCal tl,ml,sl
30020  PRINT#ch%,"READY,"!"elapsed"!"time"!;
30030  sl=DATE-kokoaika
30040  tl=INT(sl/3600):sl=sl-tl*3600
30050  ml=INT(sl/60):sl=sl-60*ml
30060  IF tl>0 THEN PRINT#ch%,tl!"h"!;
30070  IF ml>0 OR tl>0 THEN PRINT#ch%,ml!"min"!;
30080  PRINT#ch%,sl!"sec"
30090 END DEFine p_valmis
30100 :
31000 DEFine PROCedure reset(i)
31010  LOCal il:MODE i
31020  FOR il=1,2:OPEN#il,con_:END FOR il
31030  WINDOW 512,256,0,0:PAPER 0:CLS
31040  WINDOW#0,448,40-(i=4),32,216+(i=4)
31050  WINDOW#2,448,200,32,16:PAPER#2,1:INK#2,7
31060  WINDOW 448+8*(i=4),200+2*(i=4),32-4*(i=4),16-(i=4)
31070  PAPER 2*(i=8):BORDER (i=4),4*(i=4)
31080  FOR il=0,1,2:CSIZE#il,(i=4)+2*(i=8),0:END FOR il
31090  PAPER#0,0:INK#0,7-3*(i=0):INK 7:CLS
31100  SCALE 100,0,0:FILL 0
31110 END DEFine reset
31120 :
31990 STOP
32000 vsave 1:STOP
32010 vsave 2:STOP
32020 vsave 3:STOP
32030 vsave 4:STOP
32040 vsave 5:STOP
32050 vsave 6:STOP
32060 DEFine PROCedure vsave(dr)
32070  LOCal avl$(42),bvl$(42),dvl$(6,5):avl$="circledemo"
32080  bvl$=DATE$:bvl$=bvl$(1 TO 4)
32090  IF bvl$<>1992 THEN 
32100   PRINT#0,DAY$!DATE$!"Not saved, set SDATE"
32110   BEEP 4000,12:STOP:END IF 
32120  ver1%=1:ver2%=0
32130  dvl$(1)="mdv1_":dvl$(2)="mdv2_"
32140  dvl$(3)="fdk1_":dvl$(4)="fdk2_"
32150  dvl$(5)="ram1_":dvl$(6)="ram2_"
32160  bvl$=dvl$(dr)&avl$
32170  DELETE bvl$:OPEN_NEW#3,bvl$:ver%=ver2%+1
32180  PRINT#3,"1 REMark ";avl$!"(c) Timo Salmi"
32190  PRINT#3,"2 REMark ";DAY$!DATE$
32200  PRINT#3,"3 REMark version"!ver1%;".";ver%
32210  PRINT#3,"4 :"
32220  LIST#3,100 TO 32110
32230  PRINT#3,"32120  ver1%=";ver1%;":ver2%=";ver%
32240  LIST#3,32130 TO:CLOSE#3
32250  PRINT#0,"Saved"!bvl$!"version"!ver1%;".";ver%
32260 END DEFine vsave
