/ music via AM-radio (~750 kc/s)   (26.6.92)
/ rhythm with teletype ASR 33
/
/ copyright (1992)
/ National Centre for
/ Minimal- and Retro- Computing
/ Stuttgart - Germany
/
/ Klemens Krause (loops)
/ Mark Tell Schneider (music)
/
	FIELD 2
	*0017
TPNT,   0               /AUTOINC !
CNT1,	0
CNT2,	0
CNT3,	0
TON1,	0
TON2,	0
TON3,	0
TIME,   0
TIME0,  0
DUMMY,  0
/
RHYTHM,   0
        TSF             / SKIP IF PRINTER-FLAG
        JMP     .-1
        TLS
	CLA
        JMP     I RHYTHM
/
	*0200
START,	JMS	INIT
LLOOP,	ISZ     TIME0
        JMP     LT1
        OSR
        CMA
        DCA     TIME0
        ISZ     TIME
        JMP     LT1
        TAD     I TPNT  / 1. WORT: LAENGE
        SNA
        JMP     RESTRT
        DCA     TIME
        TAD     I TPNT  / 2. WORT: TON 1
        DCA     TON1
        TAD     I TPNT  / 3. WORT: TON 2
        DCA     TON2
        TAD     I TPNT  / 4. WORT: TON 3
        DCA     TON3
        TAD     I TPNT  / 5. WORT: TTY-RHYTMUS
        SZA
        JMS     RHYTHM
LT1,    ISZ	CNT1
	JMP	LDELY1  /       1.2
	TAD	TON1    / 2.6
	DCA	CNT1    / 2.6
	CLA CMA         / 1.2
        JMP     HT2     / 2.4 (INDIRECT!)
LT2,	MQL             / 1.2           = 8.8
	ISZ	CNT2
	JMP	LDELY2
	TAD	TON2
	DCA	CNT2
	CLA CMA
        JMP     HT3
LT3,	MQL
	ISZ	CNT3
	JMP	LDELY3
	TAD	TON3
	DCA	CNT3
	CLA CMA
        JMP     HTX
LTX,	MQL
	JMP	LLOOP
/
LDELY1,	NOP             /       1.2
        NOP             /       1.2
        DCA     DUMMY   /       2.6
        DCA     DUMMY   /       2.6
	JMP	LT2+1   /       1.2     = 10.0
/
LDELY2,	NOP
        NOP
        DCA     DUMMY
        DCA     DUMMY
	JMP	LT3+1
/
LDELY3,	NOP
        NOP
        DCA     DUMMY
        DCA     DUMMY
	JMP	LTX+1
/
RESTRT, OSR
        TAD     (-7605
        SZA
        JMP     START
        CDF     0       / PROGRAMM ENDET
        CIF     0
        JMP     (7605
/
INIT,   0000
	CLA
        DCA     TIME0
	TLS
	MQL
        TAD     (TOENE-1
        DCA     TPNT
        CMA
        DCA     TIME
        JMP     I INIT
/
        PAGE
	DECIMAL
/
TOENE,
/       DAUER TON1  TON2  TON3  RHYTHMUS
/ Volkslied: kein schoener Land auf dieser Welt.
        L6;   G3;   00;   00;   00
/
        L4;   C4;   G3;   E3;   00
        L4;   E4;   C4;   G3;   00
        L2;   D4;   A3;   F3;   00
        L2;   C4;   A3;   F3;   00
/ 
        L6;   D4;   H3;   G3;   00
        L6;   G3;   00;   00;   00
/ 
        L4;   C4;   G3;   E3;   00
        L4;   E4;   C4;   G3;   00
        L2;   D4;   A3;   F3;   00
        L2;   C4;   A3;   F3;   00
/
        L6;   D4;   H3;   G3;   00
        L2;   E4;   00;   00;   00
        L2;   C4;   00;   00;   00
        L2;   D4;   00;   00;   00
/
        L2;   E4;   C4;   G3;   00
        L2;   G4;   E4;   C4;   00
        L2;   F4;   D4;   A3;   00
        L2;   E4;   C4;   A3;   00
        L2;   D4;   A3;   F3;   00
        L2;   C4;   A3;   F3;   00
/
        L2;   D4;   H3;   G3;   00
        L2;   F4;   H3;   G3;   00
        L2;   E4;   A3;   F3;   00
        L2;   D4;   A3;   F3;   00
        L2;   C4;   A3;   F3;   00
        L2;   D4;   H3;   G3;   00
/
        L6;   E4;   C4;   A3;   00
        L2;   E4;   00;   00;   00
        L2;   C4;   00;   00;   00
        L2;   D4;   00;   00;   00
/
        L2;   E4;   C4;   G3;   00
        L2;   G4;   E4;   C4;   00
        L2;   F4;   D4;   A3;   00
        L2;   E4;   C4;   A3;   00
        L2;   D4;   A3;   F3;   00
        L2;   C4;   A3;   F3;   00
/
        L2;   D4;   H3;   G3;   00
        L2;   F4;   H3;   G3;   00
        L2;   E4;   A3;   F3;   00
        L2;   D4;   A3;   F3;   00
        L2;   C4;   A3;   F3;   00
        L2;   H3;   G3;   D3;   00
/
        L6;   C4;   G3;   E3;   00
/
        L6;   00;   00;   00;   00
/
/
/ ENDE DER VORSTELLUNG
        00;   00;   00;   00
	OCTAL
/
	*7600
        NOP
HLOOP,	ISZ     TIME0
        JMP     HT1
        OSR
        CMA
        DCA     TIME0
        ISZ     TIME
        JMP     HT1
        TAD     I TPNT
        SNA
        JMP     RESTRT
        DCA     TIME
        TAD     I TPNT
        DCA     TON1
        TAD     I TPNT
        DCA     TON2
        TAD     I TPNT
        DCA     TON3
        TAD     I TPNT  / 5. WORT: TTY-RHYTMUS
        SZA
        JMS     RHYTHM
HT1,	ISZ	CNT1
	JMP	HDELY1
	TAD	TON1
	DCA	CNT1
	CLA
        JMP     LT2
HT2,	MQL
	ISZ	CNT2
	JMP	HDELY2
	TAD	TON2
	DCA	CNT2
	CLA
        JMP     LT3
HT3,	MQL
	ISZ	CNT3
	JMP	HDELY3
	TAD	TON3
	DCA	CNT3
	CLA
        JMP     LTX
HTX,	MQL
	JMP	HLOOP
/
HDELY1,	NOP
        NOP
        DCA     DUMMY
        DCA     DUMMY
	JMP	HT2+1
/
HDELY2,	NOP
        NOP
        DCA     DUMMY
        DCA     DUMMY
	JMP	HT3+1
/
HDELY3,	NOP
        NOP
        DCA     DUMMY
        DCA     DUMMY
	JMP	HTX+1
/
        DECIMAL
/ LAENGE DER NOTEN
	L1=-1
	L2=-2
	L3=-3
	L4=-4
	L5=-4
	L6=-6
	L8=-8
	L12=-12
/
/ HOEHE DER NOTEN
        C1=-480
       CS1=-454
        D1=-428
       DS1=-404
        E1=-380
        F1=-360
       FS1=-340
        G1=-320
       GS1=-302
        A1=-286
       AS1=-270
        H1=-254
/
        C2=-240
       CS2=-227
        D2=-214
       DS2=-202
        E2=-190
        F2=-180
       FS2=-170
        G2=-160
       GS2=-151
        A2=-143
       AS2=-135
        H2=-127
/
        C3=-120
       CS3=-113
        D3=-106
       DS3=-101
        E3=-95
        F3=-90
       FS3=-85
        G3=-80
       GS3=-76
        A3=-71
       AS3=-67
        H3=-64
        /
        C4=-60
       CS4=-57
        D4=-53
       DS4=-50
        E4=-48
        F4=-45
       FS4=-42
        G4=-40
       GS4=-38
        A4=-36
       AS4=-34
        H4=-32
/
        C5=-30
OCTAL
      BELL=207
      NULL=200
       TAB=211
        CR=215
       PNT=256

