/	SUBROUTINE IOT (INST, AC)
/
/CALLING SEQUENCE:
/
/	CALL IOT (INST, AC)
/		<INST> THE 8-MODE INSTRUCTION TO BE
/			EXECUTED (NORMALLY AN IOT INST.)
/		<AC> THE VALUE OF THE AC WHEN THE
/			INSTRUCTION IS EXECUTED.
/
/		THE VARIABLE <AC> IS CHANGED TO BE
/		EQUAL TO THE VALUE OF THE AC AFTER THE
/		INSTRUCTION IS EXECUTED.  THIS FEATURE
/		MAY BE USED, FOR EXAMPLE, TO READ THE
/		SWITCH REGISTER WITH THE INSTRUCTION 'LAS'.
/
	BASE 0
	SECT8 IOT
	SETX INST
	STARTD
	FLDA% 0,6	/GET THE IOT INSTRUCTION POINTER
	FSTA 3
	STARTF
	FLDA% 3		/GET THE IOT INSTRUCTION
	ATX 0
	STARTD
	FLDA% 0,7
	FSTA 3
	STARTF
	FLDA% 3		/GET THE VALUE OF THE AC
	ATX 5		/PUT IT IN 8-MODE VARIABLE
	TRAP4 PDP
	XTA 5		/GET VALUE OF AC
	FSTA% 3		/RETURN IT TO CALLING PROG
	FLDA 30
	JAC
/
/
PDP,	0
	TAD AC
INST,	HLT
	DCA AC
	CIF CDF 0
	JMP% PDP
	  0
AC,	  0
ONE,	  1
TWO,	  2
END
