REM @echo off

if (%1)==() goto test_command
if (%1)==(start) goto start
goto endok

:test_command
if (%COMSPEC%)==() goto no_command
%COMSPEC% /E:9216 /C %0 start %1 %2 %3
goto endok

:no_command
echo No Command Interpreter found
goto endok

:start
call clean.bat
computil SetupC2006
if exist setenv.bat call setenv.bat
if not exist ..\C2006\*.* md ..\C2006 >nul
if exist ..\C2006\*.* call clean.bat ..\C2006\

if (%NDC2006%)==() goto enderror
if (%NDWINSYS%)==() goto enderror

copy *.pas ..\C2006
copy *.dpk ..\C2006
copy *.obj ..\C2006
copy *.inc ..\C2006
copy *.res ..\C2006
copy *.dcr ..\C2006
copy *.rsp ..\C2006

if (%NDC2006%)==() goto enderror
if (%NDWINSYS%)==() goto enderror

cd ..\C2006
REM ***************************************************
REM Compile Runtime Package Indy60
REM ***************************************************
REM IdCompressionIntercept can never be built as part of a package.  It has to be compileed separately
REM due to a DCC32 bug.
%NDC2006%\bin\dcc32.exe IdCompressionIntercept.pas /O..\Source\objs /DBCB /M /H /W /JPHN -$d-l-n+p+r-s-t-w-y- %2 %3 %4

%NDC2006%\bin\dcc32.exe Indy70.dpk /O..\Source\objs /DBCB /M /H /W /JPHN -$d-l-n+p+r-s-t-w-y- %2 %3 %4
if errorlevel 1 goto enderror
%NDC2006%\bin\dcc32.exe IdDummyUnit.pas /LIndy70.dcp /DBCB /O..\Source\objs /M /H /W /JPHN -$d-l-n+p+r-s-t-w-y- %2 %3 %4
if errorlevel 1 goto enderror
del IdDummyUnit.dcu >nul
del IdDummyUnit.hpp >nul
del IdDummyUnit.obj >nul

%NDC2006%\bin\dcc32.exe Indy70.dpk /M /DBCB /O..\Source\objs /H /W -$d-l-n+p+r-s-t-w-y- %2 %3 %4
if errorlevel 1 goto enderror
copy Indy70.bpl %NDWINSYS% >nul
del Indy70.bpl > nul

REM ***************************************************
REM Create .LIB file
REM ***************************************************
echo Creating Indy70.LIB file, please wait...
%NDC2006%\bin\tlib.exe Indy70.lib /P32 @IndyWin32.rsp >nul
if exist ..\C2006\Indy70.bak del ..\C2006\Indy70.bak >nul

REM ***************************************************
REM Compile Design-time Package RPDT30
REM ***************************************************
%NDC2006%\bin\dcc32.exe dclIndy70.dpk /DBCB /O..\Source\objs /H /W /N..\C2006 /LIndy70.dcp -$d-l-n+p+r-s-t-w-y- %2 %3 %4
if errorlevel 1 goto enderror

REM ***************************************************
REM Clean-up
REM ***************************************************
del dclIndy70.dcu >nul
del dclIndy70.dcp >nul
del Indy70.dcu >nul
del *.pas > nul
del *.dpk > nul
del *.inc > nul
del *.dcr > nul
del *.rsp > nul
REM ***************************************************
REM Design-time only unit .DCU's are not needed.
REM ***************************************************
if exist IdAbout.dcu del IdAbout.dcu >nul
if exist IdDsnBaseCmpEdt.dcu del IdDsnBaseCmpEdt.dcu >nul
if exist IdDsnPropEdBinding.dcu del IdDsnPropEdBinding.dcu >nul
if exist IdDsnRegister.dcu del IdDsnRegister.dcu >nul
if exist IdRegister.dcu del IdRegister.dcu >nul

goto endok
:enderror
call clean
echo Error!
:endok
cd ..\Source

