//===========================================================================
//
// Arch Vile
//
//===========================================================================

ACTOR Archvile 64
{
	Game Doom
	SpawnID 111
	Health 700
	Radius 20
	Height 56
	Mass 500
	Speed 15
	PainChance 10
	Monster
	MaxTargetRange 896
	+QUICKTORETALIATE 
	+FLOORCLIP 
	+NOTARGET
	SeeSound "vile/sight"
	PainSound "vile/pain"
	DeathSound "vile/death"
	ActiveSound "vile/active"
	MeleeSound "vile/stop"
	Obituary "$OB_VILE"
	States
	{
	Spawn:
		VILE AB 10 A_Look
		Loop
	See:
		VILE AABBCCDDEEFF 2 A_VileChase
		Loop
	Missile:
		VILE G 0 BRIGHT A_VileStart
		VILE G 10 BRIGHT A_FaceTarget 
		VILE H 8 BRIGHT A_VileTarget
		VILE IJKLMN 8 BRIGHT A_FaceTarget 
		VILE O 8 BRIGHT A_VileAttack
		VILE P 20 BRIGHT
		Goto See
	Heal:
		VILE "[\]" 10 BRIGHT
		Goto See
	Pain:
		VILE Q 5   
		VILE Q 5 A_Pain
		Goto See
	Death:
		VILE Q 7
		VILE R 7 A_Scream
		VILE S 7 A_NoBlocking
		VILE TUVWXY 7
		VILE Z -1
		Stop
	}
}


//===========================================================================
//
// Arch Vile Fire
//
//===========================================================================

ACTOR ArchvileFire
{
	Game Doom
	SpawnID 98
	+NOBLOCKMAP +NOGRAVITY
	RenderStyle Add
	Alpha 1
	States
	{
	Spawn:
		FIRE A 2 BRIGHT  A_StartFire
		FIRE BAB 2 BRIGHT  A_Fire
		FIRE C 2 BRIGHT  A_FireCrackle
		FIRE BCBCDCDCDEDED 2 BRIGHT  A_Fire
		FIRE E 2 BRIGHT  A_FireCrackle
		FIRE FEFEFGHGHGH 2 BRIGHT  A_Fire
		Stop
	}
}

