@echo off
echo ***
echo *** DLX Bulletin Board System, Version 7.0
echo *** System Setup
echo ***

md BIOGS
md MAILBOX
md PUB-BOX

if not exist PROMPTS goto MakeLib
copy *. *.bak

:MakeLib
md LIBRARY
if exist LIBRARY\MENU goto MakeDB
copy MENU-LIB    LIBRARY\MENU
md LIBRARY\TEXT
copy MENU-TXT    LIBRARY\TEXT\MENU
copy DLXLIST.TXT LIBRARY\TEXT
copy UPLOAD.TXT  LIBRARY\TEXT
md LIBRARY\PROGRAMS
copy MENU-PGM    LIBRARY\PROGRAMS\MENU
copy ASKYN.COM   LIBRARY\PROGRAMS
md LIBRARY\GIFS
copy MENU-GIF    LIBRARY\GIFS\MENU
copy RICHARD.GIF LIBRARY\GIFS

:MakeDB
md DATABASE
if exist DATABASE\MENU goto SOB
copy MENU-DB DATABASE\MENU
md DATABASE\DINING
copy DIN-MENU DATABASE\DINING\MENU
copy DIN-DATA DATABASE\DINING\DATA
copy DIN-HEAD DATABASE\DINING\HEADER
copy 2.TXT    DATABASE\DINING
copy 22.TXT   DATABASE\DINING
copy 16.TXT   DATABASE\DINING
copy 17.TXT   DATABASE\DINING

:SOB
echo ***
echo *** DLX can be run as either a business system or as a
echo *** social system.  If you install it as a social system,
echo *** it will ask new users their age, sex and so on, whereas
echo *** the business system does not ask this kind of thing.
echo ***
echo *** Do you wish to install DLX as a social system?
echo ***
askyn

if errorlevel 1 goto Business
copy HELP.SOC    HELP
copy MACROS.SOC  MACROS
copy MENUS.SOC   MENUS
copy PARAMS.SOC  PARAMS
copy PROMPTS.SOC PROMPTS
if not exist ESSAY      copy ESSAY.SOC    ESSAY
if not exist MULTIPLE.1 copy MULTIPLE.SOC MULTIPLE.1
if not exist PUBMAIL    copy PUBMAIL.SOC  PUBMAIL
goto Config

:Business
copy HELP.BUS    HELP
copy MACROS.BUS  MACROS
copy MENUS.BUS   MENUS
copy PARAMS.BUS  PARAMS
copy PROMPTS.BUS PROMPTS
if not exist ESSAY      copy ESSAY.BUS    ESSAY
if not exist MULTIPLE.1 copy MULTIPLE.BUS MULTIPLE.1
if not exist PUBMAIL    copy PUBMAIL.BUS  PUBMAIL

:Config
if exist \config.sys goto Done
echo FILES=35 >\CONFIG.SYS
goto Done

:Done
echo ***
echo *** Setup complete -- type DLX to start the BBS.
echo *** 

:Exit
