@echo off
rem    Ezycom DB Mailer Batch File V1.0
rem    Command Format :
rem    DBMAILER        (for node 1 operation)
rem    DBMAILER [node] (for node XX operation)
rem    [node] is the node number from 1 through to 250
rem    eg  BBS 2
set DBRIDGE=C:\DB
rem NOTE : no trailing backslash
if %1! == !     SET TASK=1
if not %1! == ! SET TASK=%1
:EXECDB
cd %DBRIDGE%
echo scan >dbridge.rsn
Db
if errorlevel 100 goto WEEKEND
if errorlevel 90  goto DAILY
if errorlevel 60  goto MAILIN
if errorlevel 50  goto BBS
if errorlevel 45  goto EDITOR
if errorlevel 1   goto EXIT
if errorlevel 0   goto EXIT
goto execdb

:DAILY
REM ************************ EZYCHEXT Routine *************************
REM Replace the <filearea> with the area number of your upload directory
REM Replace the pathname on zzap with your upload directory's file path

zzap d:\bbs\files\uploads /v+
ezychext -A200 -N%TASK% ARJ -NOBAK

REM ************************* END OF ROUTINE **************************

cd %EZY%
ezymail -scan
ezynet  -export
ezyff -C
ezymaint -I -P -U
ezyff -ID
usercomp -A -S1 -P -B10 -D90
msgcomp -LINK
goto execdb

:MAILIN
ezynet  -import -echoarea
ezymail -toss 
goto execdb

:BBS
CALL bbs.bat
goto execdb

:EDITOR
cd %DBRIDGE%
dbedit
goto execdb

:WEEKEND
rem weekend event like stuff goes here
cd %EZY%
ezyff -c
ezymaint -D
goto execdb

:EXIT
echo Ezycom is Down
